Auteur Sujet: La fibre Orange à 2Gbps, sur un routeur MikroTik 10Gbps CCR2004, via un ONT SFP+ (Lu 944727 fois)

jericho63 · « **Réponse #4848 le:** 16 août 2023 à 17:00:45 »

Citation de: zoc le 16 août 2023 à 15:10:05

Pour moi l'interface in ici doit être vlan840-TV-Stream. Accessoirement, IGMP est à destination du routeur, donc la règle pour IGMP doit aussi être dans la chaine input. Pour le RTP (8000 et 8002) je ne suis pas sur mais au début je la rajouterais aussi dans la chaine input, quitte à la virer après quelques jours si le compteur de paquets n'augmente pas...

si je mets le vlan840 en interface in, j'ai message indiquant que je ne peux pas utiliser une interface esclave et que je doit utiliser br-wan a la place.

tucs · « **Réponse #4849 le:** 16 août 2023 à 17:10:42 »

pour moi le vlan840 ne doit pas être dans le bridge br-wan, la règle firewall mangle permet d'appliquer le Cos 5 sans le bridge rule.
Ca permet de mettre le vlan840 en in au lieu de br-wan

jericho63 · « **Réponse #4850 le:** 16 août 2023 à 18:46:57 »

je vais revenir a la table mangle et rééssayer.
je vous tiens au courant

pinomat · « **Réponse #4851 le:** 16 août 2023 à 19:48:24 »

Citation de: jericho63 le 16 août 2023 à 18:46:57

je vais revenir a la table mangle et rééssayer.
je vous tiens au courant

Pour la TV, ça fonctionne très bien sur du Mikrotik. Sur le VLAN 840, il n'y a quasiment, de mémoire, que des paquets IGMP transitent et des trames de niveau 2.
Il faut deux règles mangle. 1 pour le CoS et 1 pour le DSCP (par précaution).
Il faut configuré le proxy IGMP upstream vlan 840 vers Orange, downstream vers le VLAN de la box TV.
Il faut aussi désactiver IGMP Snooping et DHCP Snooping sur le bridge. Il faut sur les ports Ethernet du Bridge autoriser Broadcast Flood+ Unknown Unicast/Multicast.
Mes règles Raw pour la VLAN 840 :

Code: [Sélectionner]

add action=accept chain=prerouting comment="Accept UDP multicast flow from OrangeIGMP" dst-address=224.0.0.0/4 dst-port=8200,8202 in-interface=OrangeIGMP protocol=udp
add action=accept chain=prerouting comment="Accept IGMP from OrangeIGMP" in-interface=OrangeIGMP protocol=igmp

Mes règles Raw pour le VLAN de la Box TV :

Code: [Sélectionner]

add action=accept chain=prerouting comment="Accept IGMP from SmartAndTV" in-interface=SmartAndTV protocol=igmp src-address-list=OrangeBoxTV

Mes règles input

Code: [Sélectionner]

add action=accept chain=input comment="Accept IGMP from OrangeIGMP/OrangeTV (already filtered in raw chain)" protocol=igmp

Mes règles forward

Code: [Sélectionner]

add action=accept chain=forward comment="Accept IPTV to SmartAndTV" dst-address=224.0.0.0/4 dst-port=8200,8202 in-interface=OrangeIGMP out-interface=SmartAndTV protocol=udp

Je regarderai si tu ne trouves pas.
Bon courage.

jericho63 · « **Réponse #4852 le:** 16 août 2023 à 21:00:04 »

bonsoir PINOMAT,
la 2e regle mangle pour le dscp elle doit ressembler à ca? je connais pas du tout

Code: [Sélectionner]

add action=change-dscp chain=output new-dscp=36 out-interface=vlan840-TV-Stream passthrough=yes

a quoi correspond "SmartAndTV"(ddecodeur) , "OrangeBoxTV"(liste d'interface qui contient le vlan840 et l’interface du decodeur?) et "OrangeIGMP"(vlan840?)?
224.0.0./4 c'est ip bidon du vlan 840 ou le subnet du decodeur?

IGMP Snooping et DHCP Snooping sont bien désactivés sur le bridge.
Dans le bridge j'ai que le vlan832 et celui ci autorise bien Broadcast Flood+ Unknown Unicast/Multicast.

tu utilises un subnet dédié pour le decodeur ou tu es sur ton lan?

merci

Citation de: pinomat le 16 août 2023 à 19:48:24

Pour la TV, ça fonctionne très bien sur du Mikrotik. Sur le VLAN 840, il n'y a quasiment, de mémoire, que des paquets IGMP transitent et des trames de niveau 2.
Il faut deux règles mangle. 1 pour le CoS et 1 pour le DSCP (par précaution).
Il faut configuré le proxy IGMP upstream vlan 840 vers Orange, downstream vers le VLAN de la box TV.
Il faut aussi désactiver IGMP Snooping et DHCP Snooping sur le bridge. Il faut sur les ports Ethernet du Bridge autoriser Broadcast Flood+ Unknown Unicast/Multicast.
Mes règles Raw pour la VLAN 840 :
Code: [Sélectionner]
add action=accept chain=prerouting comment="Accept UDP multicast flow from OrangeIGMP" dst-address=224.0.0.0/4 dst-port=8200,8202 in-interface=OrangeIGMP protocol=udp add action=accept chain=prerouting comment="Accept IGMP from OrangeIGMP" in-interface=OrangeIGMP protocol=igmpMes règles Raw pour le VLAN de la Box TV :
Code: [Sélectionner]
add action=accept chain=prerouting comment="Accept IGMP from SmartAndTV" in-interface=SmartAndTV protocol=igmp src-address-list=OrangeBoxTVMes règles input
Code: [Sélectionner]
add action=accept chain=input comment="Accept IGMP from OrangeIGMP/OrangeTV (already filtered in raw chain)" protocol=igmpMes règles forward
Code: [Sélectionner]
add action=accept chain=forward comment="Accept IPTV to SmartAndTV" dst-address=224.0.0.0/4 dst-port=8200,8202 in-interface=OrangeIGMP out-interface=SmartAndTV protocol=udpJe regarderai si tu ne trouves pas.
Bon courage.

pinomat · « **Réponse #4853 le:** 16 août 2023 à 22:32:40 »

Citation de: jericho63 le 16 août 2023 à 21:00:04

la 2e regle mangle pour le dscp elle doit ressembler à ca? je connais pas du tout

Code: [Sélectionner]

add action=set-priority chain=output comment="Set priority to 5 for IGMP packets sent to Orange" new-priority=5 out-interface=OrangeIGMP passthrough=yes protocol=igmp
add action=change-dscp chain=output comment="Set dscp to 40 for packets with priority 5sent to Orange" new-dscp=40 out-interface=OrangeIGMP passthrough=no priority=5

"SmartAndTV" : c'est le VLAN où se trouve la Box TV d'Orange.
"OrangeBoxTV" : c'est l'IP de la Box TV d'Orange
"OrangeIGMP" : VLAN840 d'Orange sur l'interface du GPON (je n'ai pas de bridge sur mon CCR2116 car ça consumme du CPU, j'utilise un CRS310 pour les CoS des paquets DHCP v4
224.0.0.0/4 : C'est pas une IP bidon

C'est le range pour les adresses multicast. Orange utilise une partie de ce range, c'est utilisé par les paquets IGMP.

J'ajoute la config igmp-proxy :

Code: [Sélectionner]

/routing igmp-proxy
set query-interval=1m quick-leave=yes
/routing igmp-proxy interface
add alternative-subnets=0.0.0.0/0 interface=OrangeIGMP upstream=yes
add interface=SmartAndTV

Dans le bridge j'ai que le vlan832 : heu, tu veux dire que tu as attaché sur la même interface Ethernet, un bridge et un VLAN ? Comme le schéma rapide ci dessous:
Ethernet -- Bridge -- VLAN832
-- VLAN840
Si c'est le cas, je ne crois pas avoir déjà ce type de config chez Mikrotik et qu'il n'y a pas d'effet de bord... Je préconiserai donc d'avoir le VLAN840 attaché au bridge, mais j'ai peut-être raté un épisode car j'ai vu ceci :

Code: [Sélectionner]

/interface bridge port
add bridge=br-wan interface=vlan832-internet
add bridge=br-wan interface=vlan840-TV-Stream

Tu utilises un subnet dédié pour le decodeur ou tu es sur ton lan? Oui, le SmartAndTV

Je crois comprendre qu'il n'y a pas de switch derrière l'ether7 ? Si oui, tu élimines déjà une source de problème avec l'IGMP Snooping/Multicast filtering qui peut interdire les flux Multicast...
Au cas où : il faut aussi s'assurer que le décodeur utilise bien les DNS Orange, ta config me semble correcte mais est-ce que le client de la Box récupère correctement l'option 6 (il faut analyser les paquets UDP 53 avec l'adresse IP de ta box).

Il faut utiliser le packet sniffer du routeur pour vérifier tout ça. Quand tu allumes la box TV, tu dois dans les traces : des paquets IGMP qui arrivent en provenance de la Box TV et qui sortent vers le VLAN 840 d'orange et des paquets DNS (udp 53) envoyé par la box vers les dns que tu as mis dans l'option DHCP 6.

Ce sera un bon début.

PS : cela fait 209 jours que le routeur n'a pas vu ma box TV d'orange (je ne l'utilise plus) !!! Donc je ne peux même pas être sûr qu'avec tous les changements que j'ai fait, elle fonctionne encore. Si besoin, je suis en congé la semaine prochaine.
Pour ne pas polluer le site, je pourrais t'aider un peu plus mais en MP.

Bonne soirée

jericho63 · « **Réponse #4854 le:** 16 août 2023 à 23:23:33 »

Citation de: pinomat le 16 août 2023 à 22:32:40

Dans le bridge j'ai que le vlan832 : heu, tu veux dire que tu as attaché sur la même interface Ethernet, un bridge et un VLAN ? Comme le schéma rapide ci dessous:
Ethernet -- Bridge -- VLAN832
-- VLAN840
Si c'est le cas, je ne crois pas avoir déjà ce type de config chez Mikrotik et qu'il n'y a pas d'effet de bord... Je préconiserai donc d'avoir le VLAN840 attaché au bridge, mais j'ai peut-être raté un épisode car j'ai vu ceci :
Code: [Sélectionner]
/interface bridge port add bridge=br-wan interface=vlan832-internet add bridge=br-wan interface=vlan840-TV-Stream

j'ai un seul bridge utilisé pour taggé le cos6 ou il y normalement le vlan832.
a un moment de mes tests j'ai rajouté le 840 que j'ai enlevé depuis.
j'ai un aruba 1930 instant on avec 4 port sfp+ faut que je regarde si je peux m'en servir pour mettre l'ont dessus , mais ce sera dans un 2e temps.

non pas de switch le decodeur est en direct
j'ai sniffer les packets pour le udp 53 et l'igmp depuis l'ip du décodeur.
dans le cas des udp 53 ils vont bien vers l'ip du dns mais dans le cas es igmp on voit juste qu'ils viennent du décodeur mais qu'ils vont vers le vlan 840.
je pars en congé une semaine vendredi, je serai de retour le 27/8 si tu es toujours dispo ensuite je ne suis pas contre un peu d'aide!
merci

Lucy-Han · « **Réponse #4855 le:** 18 août 2023 à 12:46:52 »

Bonjour à tous,

Avec l'objectif de répondre aux difficultés de @jericho63, voici quatre configurations ultra-minimalistes permettant d'utiliser l'ensemble des services Live/Replay/VOD d'Orange. La livebox est une Livebox 5 et le décodeur testé est le Livebox Play. Je tourne sous CHR, mais dans ces configurations j'ai tenté de simuler un CCR2004-1G-12S+2XS.
Dans ces configurations :
- Le WAN est sur sfp-sfpplus1 ;
- Le LAN est sur sfp-sfpplus6 ;
- Le décodeur est directement branché sur sfp-sfpplus12.

Ces configurations sont ultra-minimalistes : aucun firewall, pas d'IPv6, ... L'objectif étant de se concentrer sur le décodeur.
Il faudra peut-être adapter les serveurs DNS Orange utilisés selon la localisation.
Après activation du firewall IPv4, il faut ajouter les règles suivantes en adaptant le in-interface selon la configuration utilisée, mais l'idée générale reste la même.

Code: [Sélectionner]

/ip firewall filter add action=accept chain=forward comment="Allow Forward Multicast Orange" dst-port=8200,8202 in-interface=wan840 protocol=udp
# La ligne suivante semble inutile en pratique ...
/ip firewall filter add action=accept chain=forward comment="Allow Forward IGMP Protocol" in-interface=wan840 protocol=igmp
# La ligne suivante semble inutile en pratique ...
/ip firewall filter add action=accept chain=input comment="Allow Input Multicast Orange" dst-port=8200,8202 in-interface=wan840 protocol=udp
/ip firewall filter add action=accept chain=input comment="Allow Input IGMP Protocol" in-interface=wan840 protocol=igmp

Configuration 1 : Aucun bridge, la CoS 6 n'est pas gérée. Elle l'est, par exemple, dans un CRS305 en amont du routeur. La CoS 5 est gérée dans la table mangle.
Configuration 2 : Introduction d'un bridge. Le vlan 832 est dans le bridge et la CoS 6 est gérée dans le bridge. Le vlan 840 est en dehors du bridge et la CoS 5 est gérée dans la table mangle.
Configuration 3 : Introduction d'un bridge. Les vlan 832 & 840 sont dans le bridge, la CoS 6 est gérée dans le bridge. La CoS 5 est gérée dans la table mangle.
Configuration 4 : Introduction d'un bridge. Les vlan 832 & 840 sont dans le bridge, les CoS 5 & 6 sont gérées dans le bridge.

J'ai très rapidement testé les quatre configurations et elles semblent fonctionnelles. Les configurations sont certainement perfectibles, n'hésitez pas à me faire part de vos remarques. Enfin malgré le durcissement des règles en début d'année, toujours pas de CoS 6 à Vannes (56), aussi je ne peux garantir les règles Cos 6.

Configuration 1 :

Code: [Sélectionner]

# 2023-08-17 10:20:33 by RouterOS 7.10.2
# software id = 
#
/interface ethernet
set [ find default-name=ether1 ] auto-negotiation=no name=sfp-sfpplus1
set [ find default-name=ether2 ] auto-negotiation=no name=sfp-sfpplus6
set [ find default-name=ether3 ] disable-running-check=no name=sfp-sfpplus12
/interface vlan
add interface=sfp-sfpplus1 name=vlan832 vlan-id=832
add interface=sfp-sfpplus1 name=vlan840 vlan-id=840
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip dhcp-client option
add code=90 name=RFC-3118-Authentication value=0x0000000000000000000000xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
add code=77 name=User-Class value="'+FSVDSL_livebox.Internet.softathome.Livebox5'"
add code=60 name=Vendor-Class-Identifier value="'sagem'"
/ip pool
add name=pool1 ranges=10.28.201.100-10.28.201.200
add name=pool2 ranges=192.168.2.100-192.168.2.200
/ip dhcp-server
add address-pool=pool1 interface=sfp-sfpplus6 name=server-DHCP-lan
add address-pool=pool2 interface=sfp-sfpplus12 name=server-DHCP-deco
/ip address
add address=10.28.201.1/24 interface=sfp-sfpplus6 network=10.28.201.0
add address=192.168.2.1/24 interface=sfp-sfpplus12 network=192.168.2.0
add address=192.168.255.254 interface=vlan840 network=192.168.255.254
/ip dhcp-client
add dhcp-options=Vendor-Class-Identifier,User-Class,RFC-3118-Authentication,clientid interface=vlan832
/ip dhcp-server network
add address=10.28.201.0/24 gateway=10.28.201.1
add address=192.168.2.0/24 dns-server=80.10.246.130,81.253.149.1 gateway=192.168.2.1
/ip firewall mangle
add action=set-priority chain=output new-priority=5 out-interface=vlan840 passthrough=yes src-address-type=local
/ip firewall nat
add action=masquerade chain=srcnat out-interface=vlan832
/routing igmp-proxy interface
add interface=sfp-sfpplus12
add alternative-subnets=193.0.0.0/8,81.0.0.0/8,172.0.0.0/8,80.0.0.0/8 interface=vlan840 upstream=yes
/system note
set show-at-login=no

Configuration 2 :

Code: [Sélectionner]

# 2023-08-18 08:51:36 by RouterOS 7.10.2
# software id = 
#
/interface bridge
add name=Bridge-Wan
/interface ethernet
set [ find default-name=ether1 ] auto-negotiation=no name=sfp-sfpplus1
set [ find default-name=ether2 ] auto-negotiation=no name=sfp-sfpplus6
set [ find default-name=ether3 ] disable-running-check=no name=sfp-sfpplus12
/interface vlan
add interface=sfp-sfpplus1 name=vlan832 vlan-id=832
add interface=sfp-sfpplus1 name=vlan840 vlan-id=840
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip dhcp-client option
add code=90 name=RFC-3118-Authentication value=0x0000000000000000000000xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
add code=77 name=User-Class value="'+FSVDSL_livebox.Internet.softathome.Livebox5'"
add code=60 name=Vendor-Class-Identifier value="'sagem'"
/ip pool
add name=pool1 ranges=10.28.201.2-10.28.201.100
add name=pool2 ranges=192.168.2.2-192.168.2.100
/ip dhcp-server
add address-pool=pool1 interface=sfp-sfpplus6 name=server-DHCP-lan
add address-pool=pool2 interface=sfp-sfpplus12 name=server-DHCP-deco
/interface bridge filter
add action=set-priority chain=output dst-port=67 ip-protocol=udp log=yes log-prefix="Set CoS6 on DHCP request" mac-protocol=ip new-priority=6 out-interface=vlan832 passthrough=yes
/interface bridge port
add bridge=Bridge-Wan frame-types=admit-only-vlan-tagged interface=vlan832 pvid=832
/ip address
add address=10.28.201.1/24 interface=sfp-sfpplus6 network=10.28.201.0
add address=192.168.2.1/24 interface=sfp-sfpplus12 network=192.168.2.0
add address=192.168.255.254 interface=vlan840 network=192.168.255.254
/ip dhcp-client
add dhcp-options=Vendor-Class-Identifier,User-Class,RFC-3118-Authentication,clientid interface=Bridge-Wan
/ip dhcp-server network
add address=10.28.201.0/24 gateway=10.28.201.1
add address=192.168.2.0/24 dns-server=80.10.246.130,81.253.149.1 gateway=192.168.2.1
/ip firewall mangle
add action=set-priority chain=output new-priority=5 out-interface=vlan840 passthrough=yes src-address-type=local
/ip firewall nat
add action=masquerade chain=srcnat out-interface=Bridge-Wan
/routing igmp-proxy interface
add interface=sfp-sfpplus12
add alternative-subnets=193.0.0.0/8,81.0.0.0/8,172.0.0.0/8,80.0.0.0/8 interface=vlan840 upstream=yes
/system note
set show-at-login=no

Configuration 3 :

Code: [Sélectionner]

# 2023-08-18 08:55:53 by RouterOS 7.10.2
# software id = 
#
/interface bridge
add name=Bridge-Wan
/interface ethernet
set [ find default-name=ether1 ] auto-negotiation=no name=sfp-sfpplus1
set [ find default-name=ether2 ] auto-negotiation=no name=sfp-sfpplus6
set [ find default-name=ether3 ] disable-running-check=no name=sfp-sfpplus12
/interface vlan
add interface=sfp-sfpplus1 name=vlan832 vlan-id=832
add interface=sfp-sfpplus1 name=vlan840 vlan-id=840
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip dhcp-client option
add code=90 name=RFC-3118-Authentication value=0x0000000000000000000000xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
add code=77 name=User-Class value="'+FSVDSL_livebox.Internet.softathome.Livebox5'"
add code=60 name=Vendor-Class-Identifier value="'sagem'"
/ip pool
add name=pool1 ranges=10.28.201.2-10.28.201.100
add name=pool2 ranges=192.168.2.2-192.168.2.100
/ip dhcp-server
add address-pool=pool1 interface=sfp-sfpplus6 name=server-DHCP-lan
add address-pool=pool2 interface=sfp-sfpplus12 name=server-DHCP-deco
/interface bridge filter
add action=set-priority chain=output dst-port=67 ip-protocol=udp log=yes log-prefix="Set CoS6 on DHCP request" mac-protocol=ip new-priority=6 out-interface=vlan832 passthrough=yes
/interface bridge port
add bridge=Bridge-Wan frame-types=admit-only-vlan-tagged interface=vlan832 pvid=832
add bridge=Bridge-Wan frame-types=admit-only-vlan-tagged interface=vlan840 pvid=840
/ip address
add address=10.28.201.1/24 interface=sfp-sfpplus6 network=10.28.201.0
add address=192.168.2.1/24 interface=sfp-sfpplus12 network=192.168.2.0
add address=192.168.255.254 interface=vlan840 network=192.168.255.254
/ip dhcp-client
add dhcp-options=Vendor-Class-Identifier,User-Class,RFC-3118-Authentication,clientid interface=Bridge-Wan
/ip dhcp-server network
add address=10.28.201.0/24 gateway=10.28.201.1
add address=192.168.2.0/24 dns-server=80.10.246.130,81.253.149.1 gateway=192.168.2.1
/ip firewall mangle
add action=set-priority chain=output new-priority=5 out-interface=Bridge-Wan passthrough=yes src-address-type=local
/ip firewall nat
add action=masquerade chain=srcnat out-interface=Bridge-Wan
/routing igmp-proxy interface
add interface=sfp-sfpplus12
add alternative-subnets=193.0.0.0/8,81.0.0.0/8,172.0.0.0/8,80.0.0.0/8 interface=Bridge-Wan upstream=yes
/system note
set show-at-login=no

Configuration 4 :

Code: [Sélectionner]

# 2023-08-18 09:25:40 by RouterOS 7.10.2
# software id = 
#
/interface bridge
add name=Bridge-Wan
/interface ethernet
set [ find default-name=ether1 ] auto-negotiation=no name=sfp-sfpplus1
set [ find default-name=ether2 ] auto-negotiation=no name=sfp-sfpplus6
set [ find default-name=ether3 ] disable-running-check=no name=sfp-sfpplus12
/interface vlan
add interface=sfp-sfpplus1 name=vlan832 vlan-id=832
add interface=sfp-sfpplus1 name=vlan840 vlan-id=840
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip dhcp-client option
add code=90 name=RFC-3118-Authentication value=0x0000000000000000000000xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
add code=77 name=User-Class value="'+FSVDSL_livebox.Internet.softathome.Livebox5'"
add code=60 name=Vendor-Class-Identifier value="'sagem'"
/ip pool
add name=pool1 ranges=10.28.201.2-10.28.201.100
add name=pool2 ranges=192.168.2.2-192.168.2.100
/ip dhcp-server
add address-pool=pool1 interface=sfp-sfpplus6 name=server-DHCP-lan
add address-pool=pool2 interface=sfp-sfpplus12 name=server-DHCP-deco
/interface bridge filter
add action=set-priority chain=output dst-port=67 ip-protocol=udp log=yes log-prefix="Set CoS6 on DHCP request" mac-protocol=ip new-priority=6 out-interface=vlan832 passthrough=yes
add action=set-priority chain=output log=yes log-prefix="Set CoS5 on IGMP request" mac-protocol=ip new-priority=5 out-bridge=Bridge-Wan passthrough=yes
/interface bridge port
add bridge=Bridge-Wan frame-types=admit-only-vlan-tagged interface=vlan832 pvid=832
add bridge=Bridge-Wan frame-types=admit-only-vlan-tagged interface=vlan840 pvid=840
/ip address
add address=10.28.201.1/24 interface=sfp-sfpplus6 network=10.28.201.0
add address=192.168.2.1/24 interface=sfp-sfpplus12 network=192.168.2.0
/ip dhcp-client
add dhcp-options=Vendor-Class-Identifier,User-Class,RFC-3118-Authentication,clientid interface=Bridge-Wan
/ip dhcp-server network
add address=10.28.201.0/24 gateway=10.28.201.1
add address=192.168.2.0/24 dns-server=80.10.246.130,81.253.149.1 gateway=192.168.2.1
/ip firewall nat
add action=masquerade chain=srcnat out-interface=Bridge-Wan
/routing igmp-proxy interface
add interface=sfp-sfpplus12
add alternative-subnets=193.0.0.0/8,81.0.0.0/8,172.0.0.0/8,80.0.0.0/8 interface=Bridge-Wan upstream=yes
/system note
set show-at-login=no

LemurExpert · « **Réponse #4856 le:** 19 août 2023 à 11:49:47 »

J'ai une question vue que ça parle TV/replay etc, ça fait maintenant presque 2 ans que je tourne sous un opnsense virtualisé par proxmox qui ensuite sort en SFP+ 10gb fibre sur un switch fibre 10gb et derrière le switch rj45 1gb pour le wifi(netgear WAX206) , je ne peux pas connecter le décodeur directement en câblé car il est trop loin, y a t'il un moyen de faire marche le décodeur en wifi ? tout les tuto que je vois sont en câblé et ça ma toujours découragé

Asclèpios · « **Réponse #4857 le:** 19 août 2023 à 11:58:53 »

Citation de: LemurExpert le 19 août 2023 à 11:49:47

J'ai une question vue que ça parle TV/replay etc, ça fait maintenant presque 2 ans que je tourne sous un opnsense virtualisé par proxmox qui ensuite sort en SFP+ 10gb fibre sur un switch fibre 10gb et derrière le switch rj45 1gb pour le wifi(netgear WAX206) , je ne peux pas connecter le décodeur directement en câblé car il est trop loin, y a t'il un moyen de faire marche le décodeur en wifi ? tout les tuto que je vois sont en câblé et ça ma toujours découragé

Peut-être des CPL peuvent-il solutionner ton problème ?
Sinon plus complexe mais sans doute plus fiable une solution à base de VLAN ?

Hors sujet

De mon côté chez tout les opérateurs je passe toujours par AppleTV & Molotov … Fiable & simple pour tout ceux chez qui j’administre le réseau.
Et lors des changements d’opérateur pas de changement d’interface

LemurExpert · « **Réponse #4858 le:** 19 août 2023 à 13:53:06 »

Je suis dans une vieille bâtisse donc le CPL j'ai un gros doute mais surtout le problème c'est que mon serveur opnsense ne sort que du SFP+ (qui est entièrement utilisé d'ailleurs)
Après peut être je peux configurer ça sur mon wifi netgear

Et HS aussi: de mon côté j'utilise principalement plex et jellyfin avec un gros serveur NAS derrière

yeocti · « **Réponse #4859 le:** 19 août 2023 à 14:15:17 »

Citation de: LemurExpert le 19 août 2023 à 11:49:47

J'ai une question vue que ça parle TV/replay etc, ça fait maintenant presque 2 ans que je tourne sous un opnsense virtualisé par proxmox qui ensuite sort en SFP+ 10gb fibre sur un switch fibre 10gb et derrière le switch rj45 1gb pour le wifi(netgear WAX206) , je ne peux pas connecter le décodeur directement en câblé car il est trop loin, y a t'il un moyen de faire marche le décodeur en wifi ? tout les tuto que je vois sont en câblé et ça ma toujours découragé

Bonjour,

Normalement, le décodeur peut se connecter en WiFi.
Il faut configurer OPNSense pour que le flux IGMP soit accessible depuis le réseau WiFi.