Auteur Sujet: Configurer un MikroTik hEX RB750Gr3 sur la fibre Orange (IPv4) (Lu 17920 fois)

Ryukenden · « **le:** 08 décembre 2020 à 18:52:55 »

Mon routeur est un WRT54GL et je me suis aperçu qu'il ne peut pas suivre avec une connexion fibre, en passant directement par la Livebox j'ai 6 fois plus de debit :
WRT54GL : 50Mbps down et up
Livebox4 : 300Mbps down et up

L'interface Ethernet 100Mbps du WRT54GL ne fais pas le poids, pour le moment je replace la Livebox 4 avec SFP jusqu'a upgrade de mon reseau.
Je recherche donc un bon routeur 10Gbps flashable avec une ROM custom si possible avec interface SFP et 4 ou 5G. Avez-vous des suggestions ?

Citation de: Ryukenden le 08 décembre 2020 à 18:38:58

Justement j'ai survolé les différentes solutions et ce qui me conviendrait le mieux serait du matériel compatible pfsense, OPNsense, voir une Debian, un clone cheap relativement fiable, comme ce genre de chose posté sur le forum : https://fr.aliexpress.com/item/32819923460.html
Mais peu de retour, quelqu'un en sait un peu plus ?

Il y a aussi cette solution qui semble très intéressante mais je connaît peu routerOS et ses capacités et ce sont seulement des port 1Gbps :
https://www.eurodk.com/en/products/mt-hex/routerboard-hex-s

donc SFP + ports 1Gbps comme sur la Livebox, puis-je m'attendre à mieux que les 300Mbps down de la livebox ?

buddy · « **Réponse #1 le:** 08 décembre 2020 à 18:56:04 »

Bonjour,

La livebox tient parfaitement les débits.
Si tu as un forfait Up tu devrais avoir 1 Gbits. Si tu ne les as pas c'est probablement ton PC qui est limitant.
Si tu as un forfait Fibre tu devrais avec 400 Mbits chez Orange et 300 chez Sosh. c'est bridé par l'ONT en fonction de ton offre commerciale, donc tu n'aurais pas mieux avec un autre routeur.

Ryukenden · « **Réponse #2 le:** 08 décembre 2020 à 19:03:46 »

Citation de: buddy le 08 décembre 2020 à 18:56:04

Bonjour,

La livebox tient parfaitement les débits.
Si tu as un forfait Up tu devrais avoir 1 Gbits. Si tu ne les as pas c'est probablement ton PC qui est limitant.
Si tu as un forfait Fibre tu devrais avec 400 Mbits chez Orange et 300 chez Sosh. c'est bridé par l'ONT en fonction de ton offre commerciale, donc tu n'aurais pas mieux avec un autre routeur.

Je suis abonné Sosh, donc d’après ta réponse je ne pourrait pas espérer mieux.
Comme je tiens quand même à utiliser un routeur qui m'appartient je dois changer mon WRT54GL et j'ai besoin d'une solution sur le long terme en cas de changement d'offre par exemple.

Ryukenden · « **Réponse #3 le:** 08 décembre 2020 à 21:36:38 »

Je n'ai pas besoin du Wifi, il me faut un routeur Ethernet pur.
Pour le moment après m’être documenté sur le forum, j’hésite entre ces 2 modèles :

EdgeRouter X SFP :
https://www.eurodk.com/en/products/edgerouter/edgerouter-x-sfp

hEX S :
https://www.eurodk.com/en/products/mt-hex/routerboard-hex-s

Les deux routeurs ont un port SFP et semble tenir le 1Gbps, mais sont-ils compatible avec le SFP fournit par Orange ?
et quel OS est le meilleur entre EdgeOS, RouterOS et OPNsense ?

dmfr · « **Réponse #4 le:** 08 décembre 2020 à 23:46:16 »

Citation de: Ryukenden le 08 décembre 2020 à 21:36:38

Les deux routeurs ont un port SFP et semble tenir le 1Gbps, mais sont-ils compatible avec le SFP fournit par Orange ?
et quel OS est le meilleur entre EdgeOS, RouterOS et OPNsense ?

Ils sont tous les 3 assez différents, et il y a déjà toute la documentation sur les sujets consacrés.
Concernant le SFP orange (valable pour tous les SFP Gpon), c'est à chaque fois la loterie et d'emblée ça ne fonctionnera pas sur Ubiquiti.
La (seule) solution qui semble fiable, c'est le convertisseur MC220L. Mais vu que tu as déjà un ONT huawei, autant l'utiliser. Dans les deux cas tu n'échappera pas à un périphérique externe

Ryukenden · « **Réponse #5 le:** 09 décembre 2020 à 00:39:04 »

Citation de: dmfr le 08 décembre 2020 à 23:46:16

Ils sont tous les 3 assez différents, et il y a déjà toute la documentation sur les sujets consacrés.
Concernant le SFP orange (valable pour tous les SFP Gpon), c'est à chaque fois la loterie et d'emblée ça ne fonctionnera pas sur Ubiquiti.
La (seule) solution qui semble fiable, c'est le convertisseur MC220L. Mais vu que tu as déjà un ONT huawei, autant l'utiliser. Dans les deux cas tu n'échappera pas à un périphérique externe

Merci pour l'info concernant Ubiquiti, j’élimine déjà ce model (dommage une base debian ça me plaisait).
Concernant Mikrotik j'ai cru comprendre qu'il est compatible avec le SFP sercomm d'Orange jusqu’à une certaine version de RouterOS, des infos à ce sujet ?
En effet mon ONT Huawei serait l’idéal, mais il ne provient pas d'Orange je doit donc me débrouiller pour qu'ils enregistrent mon SN avant de compter dessus.

Ryukenden · « **Réponse #6 le:** 29 décembre 2020 à 22:29:13 »

Réception de mon MikroTik hEX (RB750Gr3) https://mikrotik.com/product/RB750Gr3

Découverte de RouterOS :
Je suis vraiment impressionné par les possibilités de configurations qu'offre les routeurs MikroTik, plus besoin de flasher un routeur avec un firmware custom, auparavant sous DD-WRT, RouterOS semble bien plus complet mais aussi plus complexe.

Je viens de passer la journée à essayer de configurer ma connexion Internet, après avoir chercher les différentes configurations pour la fibre Orange et les avoir toutes essayés, je ne peux toujours pas me connecter a Internet avec hEX.

Première configuration testée, DHCP IPv4 sans CoS 6 de 2017 :

Code: [Sélectionner]

/ip dhcp-client option
add code=77 name=userclass value=\
    "'+FSVDSL_livebox.Internet.softathome.Livebox3'"
add code=90 name=authsend value=\
    0x00000000000000000000006674692f64656D6F
/ip dhcp-client
add dhcp-options=authsend,clientid,hostname,userclass disabled=no interface=\
    vlan832-internet

Impossible d'obtenir une connexion, sachant qu'elle est sûrement obsolète j'ai cherché une configuration plus récente.

Deuxième configuration testée, DHCP IPv4 avec switch rule CoS6 de 2020 :

Code: [Sélectionner]

/interface vlan add interface=ether1 loop-protect-disable-time=00:05:00 loop-protect-send-interval=00:00:05 name=VLAN832 vlan-id=832
/interface ethernet switch rule add dst-port=67 mac-protocol=ip new-vlan-priority=6 ports=switch1-cpu protocol=udp switch=switch
/ip dhcp-client option add code=60 name=vendor-class-identifier value=0x736167656d
/ip dhcp-client option add code=77 name=userclass value=0x2b46535644534c5f6c697665626f782e496e7465726e65742e736f66746174686f6d652e4c697665626f7834
/ip dhcp-client option add code=90 name=authsend value=0x00000000000000000000001a0900000558010341010d6674692FXXXXXXXXXXXXXX
/ip dhcp-client add interface=VLAN832  dhcp-options=vendor-class-identifier,userclass,authsend add-default-route=yes default-route-distance=1 use-peer-dns=yes use-peer-ntp=yes disabled=no
/ip firewall nat add action=masquerade chain=srcnat comment="NAT LAN to WAN" out-interface=VLAN832

Cette fois-ci je ne parviens pas à ajouter la switch rule, mon routeur ne semble pas compatible alors que j'ai un ONT branché sur eth1 et non SFP.

Troisième configuration testée, DHCP IPv4 avec bridge CoS6 de 2020 :

Code: [Sélectionner]

/interface vlan add interface=sfp1 loop-protect-disable-time=00:05:00 loop-protect-send-interval=00:00:05 name=VLAN832 vlan-id=832
/interface bridge add name=Bridge-Wan
/interface bridge port add bridge=Bridge-Wan interface=VLAN832
/interface bridge filter add action=set-priority chain=output dst-port=67 ip-protocol=udp log=yes log-prefix="Set CoS6 on DHCP IPv4 request" mac-protocol=ip new-priority=6 out-interface=VLAN832 passthrough=yes
/ip dhcp-client option add code=60 name=vendor-class-identifier value=0x736167656d
/ip dhcp-client option add code=77 name=userclass value=0x2b46535644534c5f6c697665626f782e496e7465726e65742e736f66746174686f6d652e4c697665626f7834
/ip dhcp-client option add code=90 name=authsend value=0x00000000000000000000001a0900000558010341010d6674692FXXXXXXXXXXXXXX
/ip dhcp-client add interface=Bridge-Wan dhcp-options=vendor-class-identifier,userclass,authsend add-default-route=yes default-route-distance=1 use-peer-dns=yes use-peer-ntp=yes disabled=no
/ip firewall nat add action=masquerade chain=srcnat comment="NAT LAN to WAN" out-interface=Bridge-Wan

Je peux configurer le routeur mais toujours pas de connexion.

Pouvez-vous m'aider à configurer ce routeur et en apprendre les rouages (je passe par l'interface graphique via WinBox pour le configurer, je n'utilise pas la console) ?
Je n'ai pas besoin de l'IPv6, ni de la TV, ni de la VoIP.
Je cherche pour le moment à le configurer en PPPoE vie le VLAN835 (peut-être plus simple) sans succès et je ne trouve aucune configuration PPPoE sur Internet.
Merci d'avance pour votre aide.

Ryukenden · « **Réponse #7 le:** 29 décembre 2020 à 22:36:16 »

Citation de: Ryukenden le 09 décembre 2020 à 00:39:04

Merci pour l'info concernant Ubiquiti, j’élimine déjà ce model (dommage une base debian ça me plaisait).
Concernant Mikrotik j'ai cru comprendre qu'il est compatible avec le SFP sercomm d'Orange jusqu’à une certaine version de RouterOS, des infos à ce sujet ?
En effet mon ONT Huawei serait l’idéal, mais il ne provient pas d'Orange je doit donc me débrouiller pour qu'ils enregistrent mon SN avant de compter dessus.

Je précise que j'ai réussi à obtenir un ONT Orange, c'est pourquoi j'ai préféré le hEX au hEX S (plus besoin de SFP).
Tout en espérant pouvoir un jour utiliser mon ONT perso https://lafibre.info/remplacer-livebox/help-remplacer-une-livebox-4-par-un-hg8010h-perso/

Nico_S · « **Réponse #8 le:** 30 décembre 2020 à 05:16:58 »

Il me semble (pour l'avoir suivi avec mon Ubiquiti USG) que ce ne sont pas les tuto qui manquent sur ce forum. Pour tous les types, ou presque, de routeur.
Il me semblait aussi que ce n'était plus du PPPOE chez Orange (Sosh) mais du DHCP.
C'est étonnant qu'il n'y ai pas un tuto pour le HEX S.

dmfr · « **Réponse #9 le:** 30 décembre 2020 à 12:02:11 »

Citation de: Ryukenden le 29 décembre 2020 à 22:29:13

Troisième configuration testée, DHCP IPv4 avec bridge CoS6 de 2020 :
Code: [Sélectionner]
/interface vlan add interface=sfp1 loop-protect-disable-time=00:05:00 loop-protect-send-interval=00:00:05 name=VLAN832 vlan-id=832 ......

Cette config a l'air correcte, sous deux réserves :
- interface=sfp1 ? Pour un ONT externe ?
- si la connexion ne vient toujours pas, bien vérifier l'option 90 (avec tcpdump / wireshark sur la LB)
Et en dernier recours, voir si les bribes des configurations précédentes ne rentrent pas en conflit. Reset usine dans ce cas.

nscheffer · « **Réponse #10 le:** 30 décembre 2020 à 12:09:46 »

Citation de: dmfr le 30 décembre 2020 à 12:02:11

Cette config a l'air correcte, sous deux réserves :
- interface=sfp1 ? Pour un ONT externe ?
- si la connexion ne vient toujours pas, bien vérifier l'option 90 (avec tcpdump / wireshark sur la LB)
Et en dernier recours, voir si les bribes des configurations précédentes ne rentrent pas en conflit. Reset usine dans ce cas.

L'interface sfp1 n'est pas à utiliser si on a un ONT externe sauf si on utilise un stp RJ45 Cuivre.

Ryukenden · « **Réponse #11 le:** 30 décembre 2020 à 12:13:25 »

Citation de: Nico_S le 30 décembre 2020 à 05:16:58

Il me semble (pour l'avoir suivi avec mon Ubiquiti USG) que ce ne sont pas les tuto qui manquent sur ce forum. Pour tous les types, ou presque, de routeur.
Il me semblait aussi que ce n'était plus du PPPOE chez Orange (Sosh) mais du DHCP.
C'est étonnant qu'il n'y ai pas un tuto pour le HEX S.

Le PPPoE est toujours utilisé par Orange, car parfois ma LB4 bascule en PPPoE.
Effectivement, aucun tuto pour hEX que ce soit sur le forum ou par une recherche sur Google.
J'ai quand même trouvé ça (GitHub), je vais essayé de l'adapter :

Code: [Sélectionner]

# jan/13/2020 08:34:56 by RouterOS 6.46.1
#
# notes: \
#   - wan to orange ont on ether1; \
#   - lan to ap/switch on ether2; \
#   - ipv4 + ipv6 w/ fw rules; \
#   - using routeros dns cache for lan, proxying to the dns servers advertised by orange's dhcpv4 server; \
#   - direct plug your computer w/ wireshark to your livebox 4 fiber ethernet port and reboot it, inspect the dhcpv4 packat in wireshark and extract the value of 'authsend'; \
#   - the cos tag needs to be set to 6 to be accepted by the ont dhcpv4/v6 server (from default 0), this may not be required depending on your ont, check for the cos flag sent by your livebox 4 when sniffing its traffic
#
# model = RB750Gr3

/interface bridge
add admin-mac=XX:XX:XX:XX:XX:XX auto-mac=no comment=defconf name=bridge-lan protocol-mode=none
add name=bridge-wan protocol-mode=none

/interface ethernet
set [ find default-name=ether1 ] name=ether1-wan speed=1Gbps
set [ find default-name=ether2 ] name=ether2-lan speed=1Gbps
set [ find default-name=ether3 ] disabled=yes name=ether3-noop speed=1Gbps
set [ find default-name=ether4 ] disabled=yes name=ether4-noop speed=1Gbps
set [ find default-name=ether5 ] disabled=yes name=ether5-noop speed=1Gbps

/interface vlan
add comment="ONT Internet" interface=ether1-wan name=vlan832-internet vlan-id=832

/interface list
add comment=defconf name=WAN
add comment=defconf name=LAN

/ip dhcp-client option
add code=77 name=userclass value=0x2b46535644534c5f6c697665626f782e496e7465726e65742e736f66746174686f6d652e4c697665626f7834
add code=90 name=authsend value="0x0000000000000000000000XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"
add code=60 name=vendor-class-identifier value=0x736167656d

/ip pool
add name=dhcp-lan ranges=10.0.1.10-10.0.1.254

/ip dhcp-server
add address-pool=dhcp-lan disabled=no interface=bridge-lan lease-time=1w name=defconf

/ipv6 dhcp-client option
add code=11 name=authsend value="0x0000000000000000000000XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"
add code=15 name=userclass value=0x002b46535644534c5f6c697665626f782e496e7465726e65742e736f66746174686f6d652e6c697665626f7834
add code=16 name=vendor-class-identifier value=0x0000040e0005736167656d

/queue interface
set ether1-wan queue=ethernet-default
set ether2-lan queue=ethernet-default
set ether3-noop queue=ethernet-default
set ether4-noop queue=ethernet-default
set ether5-noop queue=ethernet-default

/interface bridge filter
add action=set-priority chain=output comment="CoS should be 6 for Orange DHCPv4" dst-port=67 ip-protocol=udp mac-protocol=ip new-priority=6 out-interface=vlan832-internet passthrough=yes
add action=set-priority chain=output dst-port=547 ip-protocol=udp mac-protocol=ipv6 new-priority=6 out-interface=vlan832-internet

/interface bridge port
add bridge=bridge-lan comment=defconf interface=ether2-lan
add bridge=bridge-lan comment=defconf disabled=yes interface=ether3-noop
add bridge=bridge-lan comment=defconf disabled=yes interface=ether4-noop
add bridge=bridge-lan comment=defconf disabled=yes interface=ether5-noop
add bridge=bridge-wan interface=vlan832-internet

/ip neighbor discovery-settings
set discover-interface-list=none

/ip settings
set rp-filter=strict

/ipv6 settings
set accept-redirects=no accept-router-advertisements=yes

/interface list member
add comment=defconf interface=ether1-wan list=WAN
add comment=defconf interface=bridge-lan list=LAN

/ip address
add address=10.0.1.1/24 comment=defconf interface=bridge-lan network=10.0.1.0

/ip cloud
set update-time=no

/ip dhcp-client
add dhcp-options=vendor-class-identifier,clientid,userclass,authsend disabled=no interface=bridge-wan

/ip dhcp-server network
add address=10.0.1.0/24 comment=defconf dns-server=10.0.1.1 domain=home gateway=10.0.1.1 netmask=24

/ip dns
set allow-remote-requests=yes cache-max-ttl=1d max-concurrent-queries=200 max-concurrent-tcp-sessions=50 query-server-timeout=3s

/ip dns static
add address=10.0.1.1 name=router.lan

/ip firewall filter
add action=fasttrack-connection chain=forward comment="defconf: fasttrack" connection-state=established,related
add action=accept chain=input comment="defconf: accept established,related,untracked" connection-state=established,related,untracked
add action=drop chain=input comment="defconf: drop invalid" connection-state=invalid
add action=accept chain=input comment="defconf: accept ICMP" protocol=icmp
add action=drop chain=input comment="defconf: drop all not coming from LAN" in-interface-list=!LAN
add action=accept chain=forward comment="defconf: accept established,related, untracked" connection-state=established,related,untracked
add action=drop chain=forward comment="defconf: drop invalid" connection-state=invalid
add action=drop chain=forward comment="defconf:  drop all from WAN not DSTNATed" connection-nat-state=!dstnat connection-state=new in-interface-list=WAN

/ip firewall nat
add action=masquerade chain=srcnat comment="NAT LAN to WAN" out-interface=bridge-wan

/ip service
set telnet disabled=yes
set ftp disabled=yes
set www disabled=yes
set api disabled=yes
set winbox disabled=yes
set api-ssl disabled=yes

/ip ssh
set forwarding-enabled=remote strong-crypto=yes

/ip upnp
set enabled=yes

/ip upnp interfaces
add interface=bridge-wan type=external
add interface=bridge-lan type=internal

/ipv6 address
add address=::1 from-pool=dhcp-wan interface=bridge-lan

/ipv6 dhcp-client
add add-default-route=yes dhcp-options=authsend,userclass,vendor-class-identifier interface=bridge-wan pool-name=dhcp-wan request=prefix

/ipv6 firewall filter
add action=accept chain=input connection-state=established,related,untracked
add action=drop chain=input connection-state=invalid
add action=accept chain=input in-interface-list=LAN
add action=accept chain=input protocol=icmpv6
add action=accept chain=input dst-port=546 in-interface=bridge-wan protocol=udp src-address=fe80::ba0:bab/128
add action=drop chain=input
add action=accept chain=forward connection-state=established,related,untracked
add action=drop chain=forward connection-state=invalid
add action=accept chain=forward in-interface-list=LAN
add action=accept chain=forward protocol=icmpv6
add action=drop chain=forward

/ipv6 nd
set [ find default=yes ] advertise-dns=no

/system clock
set time-zone-name=Europe/Paris

/system identity
set name="MikroTik Router"

/system note
set note="XXX XXX <xxx@xxx.xxx> - Authorized administrators only. Access to this device is monitored."

/system ntp client
set enabled=yes server-dns-names=0.pool.ntp.org,1.pool.ntp.org,2.pool.ntp.org,3.pool.ntp.org

/system resource irq rps
set ether1-wan disabled=no
set ether2-lan disabled=no
set ether3-noop disabled=no
set ether4-noop disabled=no
set ether5-noop disabled=no

/system watchdog
set watchdog-timer=no

/tool bandwidth-server
set enabled=no

/tool mac-server
set allowed-interface-list=none

/tool mac-server mac-winbox
set allowed-interface-list=none

/tool mac-server ping
set enabled=no

Auteur Sujet: Configurer un MikroTik hEX RB750Gr3 sur la fibre Orange (IPv4) (Lu 17920 fois)

Ryukenden

Configurer un MikroTik hEX RB750Gr3 sur la fibre Orange (IPv4)

buddy

Besoin de conseils pour l'achat d'un nouveau routeur

Ryukenden

Besoin de conseils pour l'achat d'un nouveau routeur

Ryukenden

Besoin de conseils pour l'achat d'un nouveau routeur

dmfr

Besoin de conseils pour l'achat d'un nouveau routeur

Ryukenden

Besoin de conseils pour l'achat d'un nouveau routeur

Ryukenden

Configurer un MikroTik hEX sur la fibre Orange

Ryukenden

Besoin de conseils pour l'achat d'un nouveau routeur

Nico_S

Configurer un MikroTik hEX sur la fibre Orange

dmfr

Configurer un MikroTik hEX sur la fibre Orange

nscheffer

Configurer un MikroTik hEX sur la fibre Orange

Ryukenden

Configurer un MikroTik hEX sur la fibre Orange