Bonjour à tous,
Je partage avec vous comment sur mon Crotik, j’ai adapté le failover 3/4G avec Orange.
En effet, le fait d’être en IP dynamique change un peu, mais la force du Mikrotik est de pouvoir faire ce que l’on veut
Pour commencer le paramétrage PPP. Dans mon cas, j’ai une clé USB Huawei 3131 connectée sur le port USB du Crotik.
J’ai mis 10 pour le poids de la route par défaut et info channel à 2 pour les SMS.
`
J’utilise le service de dynamic DNS fourni avec le routeur. Dans le menu IP / Cloud

J’ai ajouté dans la zone DNS de mon domaine une entrée qui pointe vers le DNS Name qui m’a été affecté.
Ensuite j’ai ajouté les routes ci-dessous.
/ip route
add comment=routespe distance=1 dst-address=8.8.4.4/32 gateway=86.245.40.1
add comment="Reach Google Via FTTH Only" distance=2 dst-address=8.8.4.4/32 type=blackhole
86.245.40.1 étant la gateway au moment ou je créé la route.
Le but est de forcer le chemin via Orange fibre pour le serveur 8.8.4.4 de google.
J’ai choisi celui-là car la probabilité de d’indisponibilité est extrêmement faible et hyper résilients chez google. Notez que ce serveur ne sera pas joignable en 3/4G, aucune importance pour moi.
Ensuite j’ai écrit le script CHANGE-IP, dont le but sera de changer la route pour le serveur 8.8.4.4 à chaque changement IP du fournisseur.
#affecte la gateway sur la route speciale pour le failover a chaque changement d'IP
/system scheduler set VERIFY-FTTH disabled=yes
:delay 5s
:global gw [/ip route get [find vrf-interface=vlan832] value-name=gateway];
/ip route set [find comment="routespe"] gateway=$gw;
/system scheduler set VERIFY-FTTH disabled=no
/ip cloud force-update
Ensuite, sur la configuration DHCP client ajoutez le script. Il s’exécutera à chaque changement d’IP. Important, ajoutez un commentaire « isp1 » qui servira au script de failover.
Ensuite voici le script de failover. Je l’ai nommé FAILOVER-4G
Son fonctionnement est simple. Je fais 4 pings sur l’IP de Google 8.8.4.4. Si aucun ne répond, je change le poids de la route par défaut à 100 soit supérieur à celle de la clé 3G. La bascule est fonctionnelle. Et je m’envoie un SMS pour me le signaler.
Dès que le ping répond à nouveau on remet le poids de la route à 1 et toujours un petit SMS.
#script test liaison principale
:global statusFibreOK;
:local number1 "+33607077777";
:local iptest1 "8.8.4.4";
:local date;
:local time;
:set date [/system clock get date];
:set time [/system clock get time];
:local MSGUP "$date $time Liaison fibre OK!";
:local MSGDOWN "$date $time Liaison fibre DOWN!";
:local result1 [/ping $iptest1 count=4];
:if ($result1 > 1 && $statusFibreOK != true) do={
/ip dhcp-client set [find comment="isp1"] default-route-distance=1;
/tool sms send port=usb1 phone-number=$number1 message=$MSGUP channel=2;
:set statusFibreOK true;
/log warning "Good: Liaison FTTH UP";
} else={
:if ($result1 = 0 && $statusFibreOK != false) do={
/ip dhcp-client set [find comment="isp1"] default-route-distance=100;
/tool sms send port=usb1 phone-number=$number1 message=$MSGDOWN channel=2;
:set statusFibreOK false;
/log error "ERROR: Liaison FTTH DOWN";
}
}
Ensuite dans le scheduler j’exécute ce script toutes les 30 secondes.
Simple mais efficace.