La Fibre
Datacenter et équipements réseaux => Routeurs => 
Remplacer la LiveBox par un routeur => Discussion démarrée par: Jimbo-77 le 19 juin 2023 à 09:45:59
-
Hello !
J’ai un petit comportement étrange ce matin.
Plus d’internet, je vérifie l’atténuation fibre suite aux incidents que j’ai eus et je m’aperçois que la puissance de transmission est à -40dB.
Un shut/no shut de l’interface a suffi à résoudre le souci mais je voulais savoir si vous aviez déjà eu ce type de souci.
Jim
-
Salut,
Oui, j'ai eu exactement le problème 2 fois, sur 2 installations différentes (1x chacune) en l'espace de 2 mois environ. Les ONUs sont sur des CRS305. Je ne connais pas la cause et si quelqu'un a des explications, je suis preneur ! Même si ça reste très ponctuel.
-
Un autre témoignage ici :
https://lafibre.info/remplacer-livebox/guide-de-connexion-fibre-directement-sur-un-routeur-voire-meme-en-2gbps/msg1016168/#msg1016168
-
J’avais pas précisé mais installé aussi sur un CRS305.
En tout cas, je me sens moins seul 😊.
-
Un autre témoignage ici :
https://lafibre.info/remplacer-livebox/guide-de-connexion-fibre-directement-sur-un-routeur-voire-meme-en-2gbps/msg1016168/#msg1016168
Effectivement. On verra s’il y a une amélioration avec la 7.10
-
Salut,
J'ai eu le cas 2 fois aussi en v7.8.
Il ne me semble que j'avais eu le souci en v7.7.
Depuis la v7.9, pas de problème depuis la maj (environ 1mois).
Avec quelle version de RouterOS dans le CRS305 as-tu eu le pb ?
Quelle commande exactement as-tu passé pour retrouver l'ONU et le link stp ?
-
Salut,
J'ai eu le cas 2 fois aussi en v7.8.
Il ne me semble que j'avais eu le souci en v7.7.
Depuis la v7.9, pas de problème depuis la maj (environ 1mois).
Avec quelle version de RouterOS dans le CRS305 as-tu eu le pb ?
Quelle commande exactement as-tu passé pour retrouver l'ONU et le link stp ?
Je suis en 7.9
J’ai désactivé l’interface et je l’ai réactivée derrière. Via l’interface web.
L’équivalent d’un /interface/disable <interface> et d’un /interface/enable <interface>
-
merci.
donc meme en 7.9 le problème existe...
-
J'avais fait un petit script pour monitorer l'ONU. Il faut juste changer les 2 variables iface et email.
Ce script est schedulé toutes les 10min.
Si cela peut aider...
# Check ONU Status and action if required
# version 20230620
:local iface "<ONU_IFACE>"
:local LogHeader "onu-status"
:local email "<EMAIL>"
:local msg
:local txpower
:local rxpower
:local lstatus
:local checksum
:local temperature
:global ONUStatus "OK"
/interface ethernet monitor $iface once do={:set txpower $"sfp-tx-power"; :set rxpower $"sfp-rx-power"; :set lstatus $"status"; :set temperature $"sfp-temperature"; :set checksum $"eeprom-checksum"; }
# ex : txpower:2533 rxpower:-17825 status:link-ok temperature:40 checksum:good
:set msg "$LogHeader : txpower:$txpower rxpower:$rxpower status:$lstatus temperature:$temperature checksum:$checksum"
:put "$msg"; :log info "$msg";
# check global status
if ( $txpower < 2000 or $rxpower > -1200 or $temperature > 75 or $lstatus != "link-ok" or $checksum != "good" ) do={
:set ONUStatus "RETRY"
:set msg "$LogHeader : ONU $iface status $ONUStatus WARNING !"
:put "$msg"; :log warning "$msg"
:delay 3;
/interface ethernet monitor $iface once do={:set txpower $"sfp-tx-power"; :set rxpower $"sfp-rx-power"; :set lstatus $"status"; :set temperature $"sfp-temperature"; :set checksum $"eeprom-checksum"; }
:set msg "$LogHeader : txpower:$txpower rxpower:$rxpower status:$lstatus temperature:$temperature checksum:$checksum"
:put "$msg"; :log info "$msg";
if ( $txpower < 2000 or $rxpower > -1200 or $temperature > 75 or $lstatus != "link-ok" or $checksum != "good" ) do={
:set ONUStatus "WARNING"
:set msg "$LogHeader : ONU $iface status $ONUStatus WARNING !"
:put "$msg"; :log warning "$msg"
/tool e-mail send to=$email subject="$msg"
} else={
:set ONUStatus "OK"
:set msg "$LogHeader : ONU $iface status $ONUStatus (retry OK)"
:put "$msg"; :log info "$msg"
}
}
# check tx and reboot
if ( $txpower < 0 ) do={
:set ONUStatus "FAILED"
:set msg "$LogHeader : ONU $iface status $ONUStatus FAILED, action required !"
:put "$msg"; :log error "$msg"
/tool e-mail send to=$email subject="$msg"
/interface/disable $iface
:delay 3;
/interface/enable $iface
#:set ONUStatus "REBOOT"
#/system reboot
#:delay 3;
}
-
J'avais fait un petit script pour monitorer l'ONU. Il faut juste changer les 2 variables iface et email.
Ce script est schedulé toutes les 10min.
Si cela peut aider...
# Check ONU Status and action if required
# version 20230620
:local iface "<ONU_IFACE>"
:local LogHeader "onu-status"
:local email "<EMAIL>"
:local msg
:local txpower
:local rxpower
:local lstatus
:local checksum
:local temperature
:global ONUStatus "OK"
/interface ethernet monitor $iface once do={:set txpower $"sfp-tx-power"; :set rxpower $"sfp-rx-power"; :set lstatus $"status"; :set temperature $"sfp-temperature"; :set checksum $"eeprom-checksum"; }
# ex : txpower:2533 rxpower:-17825 status:link-ok temperature:40 checksum:good
:set msg "$LogHeader : txpower:$txpower rxpower:$rxpower status:$lstatus temperature:$temperature checksum:$checksum"
:put "$msg"; :log info "$msg";
# check global status
if ( $txpower < 2000 or $rxpower > -1200 or $temperature > 75 or $lstatus != "link-ok" or $checksum != "good" ) do={
:set ONUStatus "RETRY"
:set msg "$LogHeader : ONU $iface status $ONUStatus WARNING !"
:put "$msg"; :log warning "$msg"
:delay 3;
/interface ethernet monitor $iface once do={:set txpower $"sfp-tx-power"; :set rxpower $"sfp-rx-power"; :set lstatus $"status"; :set temperature $"sfp-temperature"; :set checksum $"eeprom-checksum"; }
:set msg "$LogHeader : txpower:$txpower rxpower:$rxpower status:$lstatus temperature:$temperature checksum:$checksum"
:put "$msg"; :log info "$msg";
if ( $txpower < 2000 or $rxpower > -1200 or $temperature > 75 or $lstatus != "link-ok" or $checksum != "good" ) do={
:set ONUStatus "WARNING"
:set msg "$LogHeader : ONU $iface status $ONUStatus WARNING !"
:put "$msg"; :log warning "$msg"
/tool e-mail send to=$email subject="$msg"
} else={
:set ONUStatus "OK"
:set msg "$LogHeader : ONU $iface status $ONUStatus (retry OK)"
:put "$msg"; :log info "$msg"
}
}
# check tx and reboot
if ( $txpower < 0 ) do={
:set ONUStatus "FAILED"
:set msg "$LogHeader : ONU $iface status $ONUStatus FAILED, action required !"
:put "$msg"; :log error "$msg"
/tool e-mail send to=$email subject="$msg"
/interface/disable $iface
:delay 3;
/interface/enable $iface
#:set ONUStatus "REBOOT"
#/system reboot
#:delay 3;
}
Merci !
Je garde ça sous le coude.
D’ailleurs tu rebootes parce que la désactivation/réactivation d’interface ne fonctionne pas chez toi ? Ou c’est pour gérer le renew dhcp aussi ?
-
Non je rebootais car je n'avais pas eu le temps de tester le simple disable / enable.
J'ai un CCR2116 qui s'auto gère et fera un disable/enable des clients dhcp4/dhcp6 si perte de lien.
Chaque equipement gère ce qu'il voit sur lui-même, j'aime pas trop aller piloter un équipement tiers à partir d'un autre.
-
Non je rebootais car je n'avais pas eu le temps de tester le simple disable / enable.
J'ai un CCR2116 qui s'auto gère et fera un disable/enable des clients dhcp4/dhcp6 si perte de lien.
Chaque equipement gère ce qu'il voit sur lui-même, j'aime pas trop aller piloter un équipement tiers à partir d'un autre.
Ok 👌
Et je comprends concernant les interactions inter-équipements. Plutôt sain.
-
Du coup je me demande si le pb vient de l'ONU (pb hardaware ?) ou du switch (bug logiciel)...
J'ai également un ONT Leox qui n'a pas posé ce genre de pb. Leox fait aussi un ONU, faudrait tester avec ce dernier à la place du FS.com.
-
Du coup je me demande si le pb vient de l'ONU (pb hardaware ?) ou du switch (bug logiciel)...
J'ai également un ONT Leox qui n'a pas posé ce genre de pb. Leox fait aussi un ONU, faudrait tester avec ce dernier à la place du FS.com.
Effectivement, ça fait penser à un souci au niveau de l'ONU.
Maintenant, ça peut être une question de compatibilité. Cet ONU sur un autre routeur ne posera pas de soucis, et ce routeur avec un autre ONU ne poserait pas de souci non plus.
Et j'avoue que je n'ai pas été voir niveau log ONU pour peu qu'il y en ait...
-
Est ce que ceux qui ont mis l’ONU dans un CCR ont le problème ?
-
Hello,
Personnellement ONU est dans un CRS310 et je n'ai jamais eue ce problème. je pense que c'est un bug sur le CRS305.
-
Est ce que qqun sait où l’on voit des logs sur l’ONU ?
-
Je ne sais pas si ça peut aider, mais voici ce que je m'étais noté pour obtenir un log détaillé OCMI :
Modification du fichier /etc/init.d/omcid.sh pour rediriger en bas la console2 (2>) vers /tmp/omci.log au lieu de /dev/console
Avant :
${OMCID_BIN} -d3 -p$mib_file -o$omcc_version -i$omci_iop_mask ${lct} -l/tmp/log/debug > /dev/console 2> /dev/console &Après :
${OMCID_BIN} -d1 -p$mib_file -o$omcc_version -i$omci_iop_mask ${lct} -l/tmp/omci.log > /dev/console 2> /dev/console &
-
Je ne sais pas si ça peut aider, mais voici ce que je m'étais noté pour obtenir un log détaillé OCMI :
Modification du fichier /etc/init.d/omcid.sh pour rediriger en bas la console2 (2>) vers /tmp/omci.log au lieu de /dev/console
Avant :
${OMCID_BIN} -d3 -p$mib_file -o$omcc_version -i$omci_iop_mask ${lct} -l/tmp/log/debug > /dev/console 2> /dev/console &Après :
${OMCID_BIN} -d1 -p$mib_file -o$omcc_version -i$omci_iop_mask ${lct} -l/tmp/omci.log > /dev/console 2> /dev/console &
merci
-
Hello,
Hier, le problème est revenu sur le CRS305 et l'ONY FS.com.
Le script qui fait disable/enable a fonctionné.
C'est quand même moyen ce problème de stabilité. Est-ce que certain ont mis l'ONU dans un CCR depuis les nouvelles releases ROS ?
Car il devrait (selon MKT) fonctionner correctement maintenant.
-
Je viens d’upgrade le CRS305 en 7.10.2, on verra si ça tient mieux…
Ce serait bien de pouvoir avoir un trigger sur l’évent plutôt que d’avoir à scheduler le script.
-
Je viens d’upgrade le CRS305 en 7.10.2, on verra si ça tient mieux…
Tu as vu quelque chose dans la release note te faisant penser que ça serait corrigé ?
-
Tu as vu quelque chose dans la release note te faisant penser que ça serait corrigé ?
non :(
-
Je viens d’ouvrir un ticket au support à ce sujet.
On verra bien.
-
Même problème après upgrade en 7.10.2.
Cette fois-ci peu de temps après le précédent incident.
Ticket en cours chez Mkt avec 2 supout.
Je viens de prendre un CRS310 et je déplacerais mon ONU semaine prochaine pour voir si ça fait la même chose.
Qqun a déjà tester cet ONU : http://xbest.pl/index.php?p4878,sfp-gpon-stick-leox-lxt-010s-h-1-25-2-5g-sm-sc-20km-tx1310-rx1490-ddm-class-b ?
Perso, j’ai aussi la version ONT qui fonctionne bien, je me demande comment se comporte l’ONU dans un CRS3xxx ?
-
Merci pour ton analyse. En espérant que ça aboutisse :)
-
Ça c’est reproduit chez toi ?
Quelles versions ROS ? Quelle fréquence ?
-
Ça c’est reproduit chez toi ?
Quelles versions ROS ? Quelle fréquence ?
Non, pas pour l’instant. Ça n’est arrivé qu’une seule fois mais ça ne fait pas longtemps que j’ai cette configuration.
Sinon je suis en 7.9.
Et à la fin de semaine je suis SDF pour un mois environ. Faudra donc attendre un peu avant que je puisse partager mon expérience.
-
Merci.
ONU migré dans un CRS310 en 7.10.2.
Je me demande si nos pbs avec l’ONU ne sont pas liés au Tx fault don’t on parle ici : https://hack-gpon.org/ont-fs-com-gpon-onu-stick-with-mac/
Comme par hasard, c’est le Tx….
-
Merci.
ONU migré dans un CRS310 en 7.10.2.
Je me demande si nos pbs avec l’ONU ne sont pas liés au Tx fault don’t on parle ici : https://hack-gpon.org/ont-fs-com-gpon-onu-stick-with-mac/
Comme par hasard, c’est le Tx….
Effectivement ça pourrait être une piste.
Par contre le post est léger niveau explication/procedure d’analyse.
-
Depuis passage sur un CRS310, plus de problème.
A suivre.
-
Pas de problème non plus sur mes deux CRS305 depuis plusieurs mois :). J'ai mis en place ton script au cas où (merci pour le partage !), je ferai un retour ici si jamais le cas se produit à nouveau.
-
Plantage au bureau cette nuit, ça n'était pas arrivé depuis le printemps. Le matériel est en 7.11.2 et le script à bien détecté le TX à -40db et relancé l'interface sur le CRS305
En revanche il faut que je complète par un release DHCP et DHCPv6 sur le RB5009 car la connexion Internet est tombée et ne s'est pas rétablie.
Vous n'auriez pas par hasard un script sous la main qui détecte une perte de connexion côté routeur et qui relance la connexion ? Je chercherai sur le forum sinon.
-
J'ai mis le script que j'utilise pour monitorer ma connexion ici : https://lafibre.info/mikrotik/script-monitoring-connexion-ipv4-et-ipv6/ (https://lafibre.info/mikrotik/script-monitoring-connexion-ipv4-et-ipv6/)
-
Nickel, merci fttmeh, je vais mettre ça en place ;)
-
Salut,
moi j'ai ça :
# check wan1 and release/restart dhclient as required
#
# version 20230327
:local dhclient4ID "0"
:local dhclient6ID "0"
:local iface "<ton_interface_dhcp_vlan832>"
:local srcAddress "<ton_ip_public>"
:local addrTest1 "1.0.0.1"
:local addrTest2 "9.9.9.10"
:local addrTest3 "8.8.4.4"
:local countTest 3
:local addrONU "<ton_ip_ONU>"
:local addrONT "<OU_ton_ip_ONT>"
:local LogHeader "check-dhclient"
:local email "<ton_email>"
# disable (0) or enable (1) route recursive test
:local routeRecursive "0"
:local msg
:local addr
:local routeStatus
:local pingStatus
:local linkStatus
:local dhclient4Status
:local dhclient6Status
# global vars
:local Date [/system clock get date];
:local Time [/system clock get time];
:local Hour [:pick [/system clock get time] 0 2];
:global dhclientStatus
:global dhclientRun
:global dhclientResetID
# init Status and ResetID
:if ( [:tostr $dhclientStatus] = "" ) do={
:set dhclientStatus ($Time . " " . $Date);
}
:if ( [:tostr $dhclientResetID] = "" ) do={
:set dhclientResetID "-1";
}
:set dhclientRun ($Time . " " . $Date);
:set dhclientStatus "OK"
:set linkStatus "OK"
:set routeStatus "OK"
:set pingStatus "OK"
#
# define vars
#
if ( [:tostr $srcAddress] = "" ) do={
:set srcAddress ([/ip/address print detail as-value where interface=$iface ]->0->"address")
:local delim [:find $srcAddress "/" 0]; :set srcAddress [ :pick $srcAddress 0 $delim ]
:set msg "$LogHeader : defined src-address=$srcAddress"
:put "$msg"
if ( [:tostr $srcAddress] = "" ) do={
:set msg "$LogHeader : null src-address=$srcAddress"
/tool e-mail send to=$email subject="$msg"
:set dhclientStatus "ERROR"
:error "$smg"
}
}
#
# test ONU/ONT
#
:set addr "$addrONU"
if ([/ping $addr count=3]=0) do={
:set msg "$LogHeader : link ONU $addr FAILED !"
:put "$msg"; :log warning "$msg"
:set dhclientStatus "ONU"
# test ONT
:set addr "$addrONT"
if ([/ping $addr count=3]=0) do={
:set msg "$LogHeader : link ONT $addr FAILED !"
:put "$msg"; :log error "$msg"
:set dhclientStatus "ONT"
:set linkStatus "FAILED"
:set msg "$LogHeader : link ONU/ONT FAILED !"
/tool e-mail send to=$email subject="$msg"
:set dhclientStatus "ERROR"
:error "$msg"
} else={
:set msg "$LogHeader : link ONT $addr alive"
:put "$msg";
#:log info "$msg"
}
} else={
:set msg "$LogHeader : link ONU $addr alive"
:put "$msg";
#:log info "$msg"
}
#
# test recursive routes
#
if ( [:tostr $routeRecursive] = "1" ) do={
:set addr "$addrTest1/32"
:retry command={/ip route get [ find dst-address=$addr active ]} delay=1 max=3 on-error={:set routeStatus "FAILED"}
if ($routeStatus = "FAILED") do={
:set msg "$LogHeader : route $addr FAILED !"
:put "$msg"; :log warning "$msg"
:set dhclientStatus "WARNING"
:delay 3
:set addr "$addrTest2/32" ; :set routeStatus "WARNING"
:retry command={/ip route get [ find dst-address=$addr active ]} delay=1 max=3 on-error={:set routeStatus "FAILED"}
if ($routeStatus = "FAILED") do={
:set msg "$LogHeader : route $addr FAILED !"
:put "$msg"; :log warning "$msg"
:set dhclientStatus "WARNING"
:delay 3
:set addr "$addrTest3/32" ; :set routeStatus "WARNING"
:retry command={/ip route get [ find dst-address=$addr active ]} delay=1 max=3 on-error={:set routeStatus "FAILED"}
if ($routeStatus = "FAILED") do={
:set msg "$LogHeader : route $addr FAILED !"
:put "$msg"; :log error "$msg"
:set routeStatus "FAILED"
:set dhclientStatus "FAILED"
} else={
:set msg "$LogHeader : route $addr active"
:put "$msg";
#:log info "$msg"
}
} else={
:set msg "$LogHeader : route $addr active"
:put "$msg";
#:log info "$msg"
}
} else={
:set msg "$LogHeader : route $addr active"
:put "$msg";
#:log info "$msg"
}
} else={
:set msg "$LogHeader : skip recursive route check"
:put "$msg";
}
#
# test ping
#
:set addr "$addrTest1"
if ([/ping $addr src-address=$srcAddress count=$countTest ]=0) do={
:set msg "$LogHeader : ping src-address=$srcAddress $addr FAILED !"
:put "$msg"; :log warning "$msg"
:set dhclientStatus "WARNING"
:set addr "$addrTest2" ; :set pingStatus "WARNING"
if ([/ping $addr src-address=$srcAddress count=$countTest ]=0) do={
:set msg "$LogHeader : ping src-address=$srcAddress $addr FAILED !"
:put "$msg"; :log warning "$msg"
:set dhclientStatus "WARNING"
:set addr "$addrTest3" ; :set pingStatus "WARNING"
if ([/ping $addr src-address=$srcAddress count=$countTest ]=0) do={
:set msg "$LogHeader : ping src-address=$srcAddress $addr FAILED !"
:put "$msg"; :log error "$msg"
:set dhclientStatus "FAILED"
:set pingStatus "FAILED"
} else={
:set msg "$LogHeader : ping src-address=$srcAddress $addr alive"
:put "$msg";
#:log info "$msg"
}
} else={
:set msg "$LogHeader : ping src-address=$srcAddress $addr alive"
:put "$msg";
#:log info "$msg"
}
} else={
:set msg "$LogHeader : ping src-address=$srcAddress $addr alive"
:put "$msg";
#:log info "$msg"
}
# finally get dhclient current status
:set dhclient4Status [/ip dhcp-client get [find where interface=$iface] status]
if ( $dhclient4Status != "bound" ) do={
:set msg "$LogHeader : dhclient4 current status $dhclient4Status FAILED !"
:put "$msg"; :log error "$msg"
:set dhclientStatus "FAILED"
} else={
:set msg "$LogHeader : dhclient4 current status $dhclient4Status"
:put "$msg";
#:log info "$msg"
}
:set dhclient6Status [/ipv6 dhcp-client get [find where interface=$iface] status]
if ( $dhclient6Status != "bound" ) do={
:set msg "$LogHeader : dhclient6 current status $dhclient6Status FAILED !"
:put "$msg"; :log error "$msg"
:set dhclientStatus "FAILED"
} else={
:set msg "$LogHeader : dhclient6 current status $dhclient4Status"
:put "$msg";
#:log info "$msg"
}
#
# status
#
:set msg "$LogHeader : status src-address:$srcAddress routeStatus:$routeStatus pingStatus:$pingStatus dhclient4Status:$dhclient4Status dhclient6Status:$dhclient6Status dhclientStatus:$dhclientStatus linkStatus:$linkStatus resetID:$dhclientResetID"
:put "$msg"; :log info "$msg"
#
# final decision
#
if ( $dhclientStatus = "FAILED" or $pingStatus = "FAILED" or $routeStatus = "FAILED" ) do={
if ( $dhclientResetID = "$Hour" ) do={
:set msg "$LogHeader : skipping reset interface $iface (resetID:$dhclientResetID)"
:put "$msg"; :log warning "$msg"
} else={
:set msg "$LogHeader : reset interface $iface (and dhclient4:$dhclient4ID dhclient6:$dhclient6ID)"
:put "$msg"; :log warning "$msg"
:set dhclientStatus "RESET"
:set dhclientResetID "$Hour"
/tool e-mail send to=$email subject="$msg"
/interface/disable $iface
:delay 3
/interface/enable $iface
#:delay 6
#/ip/dhcp-client/release numbers=$dhclient4ID
#:delay 3
#/ipv6/dhcp-client/release numbers=$dhclient6ID
:delay 3
:set msg "$LogHeader : reset interface $iface finished"
:put "$msg"; :log info "$msg"
/tool e-mail send to=$email subject="$msg"
}
} else={
:set msg "$LogHeader : everything is fine"
:put "$msg";
#:log info "$msg"
}
-
Merci cyayon ! Je vais pouvoir m'inspirer du meilleur des 2 mondes ;D
-
le mien semble moins élégant, peut-être trop monolithique ...
-
J'ai revu mon script entre temps, pour faire un seul qui fasse les checks en IPv4 et IPv6.
Si les variables testv4 et testv6 ont une valeur de 1, les tests correspondants seront faits.
Il faut aussi deux scripts pour faire le restart du client DHCPv4 et DHCPv6.
checkInetGateways:
:local defgw4
:local defgw6
:local testv4 1
:local testv6 1
:local dorestarts 0
:do { :set defgw4 [ /ip route get number=[find dst-address="0.0.0.0/0" and active ] value-name=gateway ] } on-error={ :log error "CONNECTIVITY-CHECK (IPv4): No gateway detected, exiting." ; :set testv4 0 }
:do { :set defgw6 [ /ipv6 route get number=[find dst-address="::/0" and active ] value-name=gateway ] } on-error={ :log error "CONNECTIVITY-CHECK (IPv6): No gateway detected, exiting." ; :set testv6 0 }
:local pingresult4 [ /ping address=$defgw4 count=3 interval=1.5s ]
:local pingresult6 [ /ping address=$defgw6 count=3 interval=1.5s ]
:if ( ($pingresult4 = 0) and ($testv4 = 1) ) do={
:log info "CONNECTIVITY-CHECK (IPv4): Failed ping to default gateway, restarting dhcp client"
:set dorestarts 1
}
:if ( ($pingresult6 = 0) and ($testv6 = 1) ) do={
:log info "CONNECTIVITY-CHECK (IPv6): Failed ping to default gateway, restarting dhcp client"
:set dorestarts 1
}
:if ( $dorestarts = 1 ) do={
/system/script/run restartDHCPv4client
:delay 3s
/system/script/run restartDHCPv6client
}
restartDHCPv4client:
/ip dhcp-client release [find interface=vlan832-wan ]
/ip dhcp-client disable [find interface=vlan832-wan ]
:delay 2s
/ip dhcp-client enable [find interface=vlan832-wan ]
restartDHCPv6client:
/ipv6 dhcp-client release [find interface=vlan832-wan ]
/ipv6 dhcp-client disable [find interface=vlan832-wan ]
:delay 2s
/ipv6 dhcp-client enable [find interface=vlan832-wan ]
-
J'ai tenté de mettre en place le script de fttmeh qui correspond bien à ce que je souhaite faire.
A mon premier test j'ai tout explosé ;D
Pour information, j'avais activé la fonction "Detect Internet" sur mon routeur, mais celle-ci ne se contente pas de vérifier si la connexion internet est bien active en affichant un joli graph sur l'application mobile : en cas de désactivation du client DHCP, elle recrée un client DHCP dynamique (non fonctionnel), non supprimable et empêchant de réactiver mon client DHCP. J'étais obligé de couper la fonction "Detect Internet" pour reprendre la main. Donc dans le cadre de la mise en place du script, soit je désactive la fonction "Detect Internet", soit je me contente d'un Release qui a toujours été suffisant dans mon cas pour retrouver la connexion.
Ensuite, j'ai un cas étrange. J'ai 2x installations similaires (RB5009+CRS305), et sur une installation je peux pinger la passerelle Orange, sur l'autre impossible. Sauf erreur de ma part, les configurations sont identiques.
Savez-vous si Orange désactive la réponse au ping sur certaines passerelles ?
-
Salut,
Attention, dans certains cas chez Orange, la gateway n’est pas pingable.
Je crois qu’avec un abonnement GP ça fonctionne mais pas avec un abonnement PRO et/ou avec une IP fixe.
C’est pour cela que dans mon script, je ping d’autres IP et avec des retry pour être certain de ne pas restart le dhclient en permanence.
-
Super, merci cyayon pour la précision !
Ce sont 2 offres pro avec IP fixe, et donc dans un cas une passerelle est pingable et l'autre non.
Je vais donc faire comme toi et me baser sur d'autres IP ;)
-
Pour information, j'ai mis à jour mes équipements en 7.12, avec pas mal de modifications concernant la gestion du SFP et une note sur le forum Mikrotik :
Notice - SFP/QSFP functionality has been refactored for consistent behavior and better scalability. Now, compliance with SFP/SFP+/QSFP MSA standard is mandatory. This may cause issues with SFP/QSFP modules that are not fully compliant. All current MikroTik modules abide this standard.
Moins de 12h après la mise à jour sur le CRS305, j'ai eu un TX à -40db dans la nuit mais les scripts ont tout remis en place :)
Cela fait à présent 3 jours que c'est stable, mais le problème est toujours présent.
-
Merci pour l'info.
Il y a vraiment un problème entre le CRS305 et cet ONU.
Depuis que je suis sur CRS310 plus de problème.
Faudrait tester cela sur un CRS305 : https://hack-gpon.org/ont-fs-com-gpon-onu-stick-with-mac/ (section TX Fault / Serial)
-
Oui, j'hésite à essayer cela car cela désactive le port série et ça m'a dépanné dans le passé. A voir
-
Aller, je me suis lancé, j'ai appliqué le paramétrage Hack GPON sur l'ONU de la maison. Pour le moment ça fonctionne, j'appliquerai la même chose au bureau dans quelques jours si tout va bien.
On va voir s'il y a du mieux, je vous tiendrai au courant.
-
Cool, faut compter au moins 2 ou 3 mois avant de crier victoire.
-
Modification appliquée au bureau jeudi dernier, on se reparle dans quelques mois :D (ou avant si ça merde toujours ::))
-
Modification appliquée au bureau jeudi dernier, on se reparle dans quelques mois :D (ou avant si ça merde toujours ::))
merci, on se tient au courant.
-
A noter également que depuis RouterOS 7.12 il y a de nouvelles options de vitesse pour les interfaces Ethernet.
J'ai basculé de 2.5G baseT à 2.5G baseX vu que c'est de la fibre. Pas sûr que ça change grand-chose toutefois.
https://help.mikrotik.com/docs/display/ROS/Ethernet
-
C'est bizarre cette histoire.
Le 12/11, passage en 7.12 (https://lafibre.info/remplacer-livebox/onu-fs-com-tx-power-a-40db/msg1043512/#msg1043512), moins de 12 h plus tard plantage, uniquement sur mon installation du bureau.
Le scripts ont rétabli la connexion et depuis RAS.
Ce jour, passaage en 7.13, 7h plus tard plantage, de nouveau uniquement sur mon installation du bureau.
La connexion est repartie grâce au scripts.
J'attends la prochaine mise à jour ... ???
-
Je suis passé en 7.12 hier en me disant que je n’avais vu de retours négatifs… 🙄
Ceci étant pour l’instant, pas de souci. Mais ça fait moins de 24h.
-
Depuis le changement de switch vers un crs310, plus de problème.
-
Je confirme que depuis le passage en 7.13 depuis ce week-end, j’ai déjà eu deux fois le souci.
MikroTik avait adressé sur ce souci ?
-
Je ne sais pas si cyayon a eu un retour du support.
Depuis le passage en 7.13, j'ai eu 3 crashs en 4 jours au bureau mais rien à la maison. J'ai redémarré le CRS305 au bureau il y a 24h.
En 1 an, j'ai eu un seul crash à la maison et peut-être 8 fois plus au bureau (sans que le switch ne soit plus sollicité)
J'ai la sensation que quelque chose cloche au niveau du CRS305 dans certaines situations. La config entre mon domicile et le bureau est identique, seules les module SFP sont différents (ONU FS, XS+DA0001 et 1 module 10Gtek à domicile, ONU FS, XS+DA0001 et 2 modules Mikrotik S+85DLC03D au bureau)
Aussi, on peut conclure que la modification du TX fault comme indiquée ici ne change rien : https://hack-gpon.org/ont-fs-com-gpon-onu-stick-with-mac/ :)
-
Je n’ai jamais eu de retour de MKT sur ce ticket…
Je crois qu’on est plusieurs à avoir des pb avec cet ONU dans le CRS305. Ceux qui utilisent des CRS309 ou 310 n’ont pas de pb.
-
Je n’ai jamais eu de retour de MKT sur ce ticket…
Je crois qu’on est plusieurs à avoir des pb avec cet ONU dans le CRS305. Ceux qui utilisent des CRS309 ou 310 n’ont pas de pb.
T’as le numéro ou un lien ?
-
https://help.mikrotik.com/servicedesk/servicedesk/customer/portal/1/SUP-122339
-
Pour voir si ce n'est pas un problème de stabilité de l'alimentation qui pourrait expliquer les écarts de crashs entre mes 2 installations, je bascule l'alimentation des CRS305 du bloc secteur 24V vers du PoE 48V (mes RB5009 sont PoE). Ça ne coûte rien (sans y croire toutefois).
-
C'est toutefois une bonne idée. Quand j'utilisais mon CRS305, il était connecté en POE sur un CRS328 (interface admin) ET sur son transfo fournit par défaut.
-
Bon, ben passage hier soir à domicile sur le PoE In (sans PSU) => RAS
Ce matin, TX à -40 vers 6h15 au bureau. Passage sur PoE à 9h (sans PSU également) => TX à -40 vers 12h45 :-\
==> Le passage au PoE ne change rien, mais les problèmes se concentrent toujours au bureau, je ne sais pas expliquer pourquoi :o
La seule différence qui me reste est le taux d'humidité qui est plus élevé dans la petite baie du bureau qu'à la maison ;D
Clairement, le passage à RouterOS 7.13 a aggravé la situation. J'ai un CRS328 dans un carton que je vais peut-être ressortir, mais c'est vraiment sortir la grosse artillerie alors que le CRS305 devrait être largement suffisant et plus économe en énergie.
-
Bonjour,
Peut-être que c'est l'ONU qui a un souci à votre bureau ?
Avez-vous essayé de les interchanger ?
-
Je crois qu’on peut activer les logs sur l’ONU.
Il faut se connecter en SSH et modifier un script je crois…
Comme le pb se reproduit souvent au bureau, c’est facile de prendre une trace.
Pour les logs, j’avais noté ça :
To redirect logs to /tmp/omci.log instead of /dev/console, update /etc/init.d/omcid.sh
${OMCID_BIN} -d1 -p$mib_file -o$omcc_version -i$omci_iop_mask ${lct} -l/tmp/omci.log > /dev/console 2> /dev/console &
-
Bonjoure à tous,
Crash cette nuit à 2h45 à la maison, ce n'était pas arrivé depuis le printemps de mémoire ! :( Cette version 7.13 n'apporte rien de bon (à part le wifi qui offre enfin des bonnes perfs sur les anciennes bornes AC, c'est le jour et la nuit).
Merci pour les suggestions d'inversion ou de logs, mais je me demande si je vais continuer à dépenser de l'énergie sur ce sujet et peut-être basculer vers des ONT Leox...
Ou alors flasher les ONU avec un autre firmware ? Je ne sais plus s'il y en a des plus stables.
Je vous tiens au courant si je trouve un peu de patience ;D
-
Je pense qu’activer les logs permettrait de comprendre le pb.
Pour ma part, j’ai remplacer le crs305 pour un crs310 et plus de pb. Le crs305 est maintenant dans mon bureau à la maison.
J’ai aussi un Leox, c’est stable et ça fonctionne sans pb.
Je ne me risquerais pas à flasher l’ONU avec un autre firmware.
-
Je viens de remplacer au bureau le CRS305 par un CRS328(-24P-4S+RM) que je possédais déjà, on va voir s'il y a du mieux. C'est le même processeur / switch chip que le CRS305 (98DX8208).
A la maison je n'ai qu'une petite armoire 10", donc je reste avec mon RB5009 et CRS305, à l'occasion j'activerai les logs sur l'ONU (pas eu d'autre plantage chez moi depuis 6 jours, contre 2x au bureau)
-
Un truc que j'ai fait récemment, c'est la mise à jour du firmware (routerboard). Jusqu'à récemment je n'avais pas vu que ça existait et donc que c'était possible.
Donc je tournais toujours avec le firmware d'origine malgré les mises à jour de routerOS.
J'ai fait cette mise à jour il y a quelques jours et pour l'instant, pas de souci.
Evidemment ce n'est pas suffisant pour considérer que c'est la solution. Mais pour ceux qui ont le souci, et qui n'ont pas effectué les mises à jour, ça se tente :)
Au besoin : https://help.mikrotik.com/docs/display/ROS/RouterBOARD (https://help.mikrotik.com/docs/display/ROS/RouterBOARD)
-
Je mets à jour ce firmware à chaque mise à jour majeure de RouterOS, et ça n'a jamais eu d'influence sur ce problème, malheureusement...
Pour info, j'ai ouvert un ticket chez Mikrotik avec le détail du problème et mes tests, pas de retour pour le moment (ça fait 3 jours).
J'ai récupéré les logs OMCI côté ONU au moment des plantage, mais rien ne me parle. Je peux les partager ici si vous voulez jeter un oeil.
Plus de soucis avec le CRS328 à la place du CRS305 au bureau, tout est super stable.
J'ai tenté le firmware 7.14beta8 sur le CRS305 depuis 3 jours à la maison, et pour le moment ça tient (alors que j'avais presque une coupure quotidienne depuis la 7.13). On va attendre encore un peu quand même pour voir si il y a du mieux.
-
Je mets à jour ce firmware à chaque mise à jour majeure de RouterOS, et ça n'a jamais eu d'influence sur ce problème, malheureusement...
Ok, c'était trop beau :)
Pour info, j'ai ouvert un ticket chez Mikrotik avait le détail du problème et mes tests, pas de retour pour le moment (ça fait 3 jours).
J'ai récupéré les logs OMCI côté ONU au moment des plantage, mais rien ne me parle. Je peux les partager ici si vous voulez jeter un oeil.
Perso, je ne pense pas pouvoir apporter quelque chose.
Plus de soucis avec le CRS328 à la place du CRS305 au bureau, tout est super stable.
J'ai tenté le firmware 7.14beta8 sur le CRS305 depuis 3 jours à la maison, et pour le moment ça tient (alors que j'avais presque une coupure quotidienne depuis la 7.13). On va attendre encore un peu quand même pour voir si il y a du mieux.
Intéressant. Cependant, récemment j'avais la coupure plutôt rapidement après un reboot, mais par la suite plutôt stable.
Mais peut être juste une coïncidence...
-
Mikrotik ça a l'air d'être un peu merdique comme matos ... Entre les personnes qui ont des problèmes de bande passante en XGS-PON et les ONU qui crash dessus ...
-
Je ne pense pas qu'il faille dévaloriser tout le matériel Mikrotik pour un problème spécifique à 1 modèle d'ONU avec 1 modèle de switch chez eux (je n'ai pas suivi les problèmes de perf XGS-PON - je ne suis pas encore concerné ;D)
Pour le reste ça fonctionne plutôt pas mal. Il faudrait juste qu'ils coupent le développement de RouterOS 7 en une branche vraiment stable ou LTS et une branche avec des release plus régulière comme actuellement car je conçois que sur des systèmes critiques ça pourrait être un peu limite.
Mais personnellement je suis satisfait dans l'ensemble.
Par ailleurs, depuis que j'ai appliqué la 7.14beta8 sur le CRS305 à la maison depuis 1 semaine je n'ai plus de soucis. A voir si ça continue de tenir, mais il ont dû toucher quelque chose au niveau du soft car c'est bien plus stable que la 7.13.
Toujours aucun problème sur le CRS328.
-
Je continue à mettre à jour ce fil :)
J'avais ouvert un ticket chez Mikrotik, fourni un supout.rif après un TX à -40db, mais ils ne savent pas vraiment ou chercher.
Du coup j'ai installé un CRS310-1G-5S-4S+ à la place du CRS305, la connexion est stable. Mais je ne me sers que des 4x ports SFP+ et le ventilateur est bruyant (Il est ON/OFF, pas de vitesse variable, et 13000RPM plein pot).
Avant hier est sortie la version 7.15beta4 avec notamment :
*) sfp - improved "sfp-tx-power" value monitoring in certain cases;
Du coup j'ai réactivé le CRS305 avant-hier soir avec cette version, et je vous dis si c'est mieux (ok pour le moment)
-
Je continue à mettre à jour ce fil :)
J'avais ouvert un ticket chez Mikrotik, fourni un supout.rif après un TX à -40db, mais ils ne savent pas vraiment ou chercher.
Du coup j'ai installé un CRS310-1G-5S-4S+ à la place du CRS305, la connexion est stable. Mais je ne me sers que des 4x ports SFP+ et le ventilateur est bruyant (Il est ON/OFF, pas de vitesse variable, et 13000RPM plein pot).
Avant hier est sortie la version 7.15beta4 avec notamment :
*) sfp - improved "sfp-tx-power" value monitoring in certain cases;
Du coup j'ai réactivé le CRS305 avant-hier soir avec cette version, et je vous dis si c'est mieux (ok pour le moment)
merci
-
Toujours aucun problème avec la 7.15beta depuis 9 jours (avec mise à jour 7.15beta4 à 7.15beta6 il y a 4 jours)
J'ai demandé au support si cette correction pouvait influer sur notre problème, et voici la réponse (assez générique) :
This change may also affect the devices you are using. This fix has improved the TX-Power monitoring functionality. Please keep us informed of how your connections will continue to work for you with this improvement.
This will be important feedback and observations for us.
On va se laisser encore un peu de temps quand même ...
-
Petit update ce soir : devant la stabilité de mon installation à domicile, j'ai aussi basculé l'installation du bureau en 7.15beta puis rc (7.15rc2 aujourd'hui)
Alors que je pouvais avoir 5 crashs par mois par installation en début d'année, plus aucun problème sur les 2 installations depuis près de 2 mois. Je pense que MikroTik a touché le bon bout de code ;D
J'espère que ce problème est vraiment derrière nous à présent !
-
Petit update ce soir : devant la stabilité de mon installation à domicile, j'ai aussi basculé l'installation du bureau en 7.15beta puis rc (7.15rc2 aujourd'hui)
Alors que je pouvais avoir 5 crashs par mois par installation en début d'année, plus aucun problème sur les 2 installations depuis près de 2 mois. Je pense que MikroTik a touché le bon bout de code ;D
J'espère que ce problème est vraiment derrière nous à présent !
Merci pour le feedback.
Je testerai ça dès que la GA sera sortie.
Par contre, en général j’ai le souci assez rapidement après le reboot du switch mais ensuite plutôt stable.
-
Pareil, j'avais remarqué que ça arrivait souvent dans les heures suivant le reboot du switch.
Pour le coup, je les ai redémarrés régulièrement à chaque mise à jour de la 7.15b ou rc, et je n'ai jamais eu de problème :fingercross: